PC-6001のROMカートリッジをArduino Mega256 R3で読み込む

PC-6001用のROMカートリッジを、Arduino Mega2560 R3で吸い出してみました。

用意するもの

• カードエッジコネクタ
• ユニバーサル基板
• ピンヘッダ
• ピンヘッダ用ケーブル
• Arduino Mega2560 R3

Arduino Mega2560 R3は純正品ではなく安価な互換品を使いましたが問題なく動きました。

ピンヘッダやピンケーブルも何でもOKですが、オスメスを間違えないでください。

工作

ユニバーサル基板にカードエッジコネクタとピンヘッダを並べて、そのまま平行に繋げるようにハンダ付けしていきます。シール基板とかジャンパ線とかなんでもOKです。

• 端子が50本あるので、手軽な方法で工作してください
• 実際に使うのは25本程度なので、必要なピンだけでもOKです
• この時点では信号の意味を意識する必要はないです
• ROMカートリッジの厚さを考慮してピンヘッダを配置してください（やらかしやすいです）

十字配線ユニバーサル基板を使って配線をカットする方が楽かもですね（私は使ったことがないのですが）

ピンヘッダケーブルの配線

PC-6001側のピンと、Arduino側のピンを繋いでいきます。

• 下の表では、Arduino側番号の並びが一部逆順になっていますが、記載ミスではありません
• PC-6001エッジコネクタ側の端子に⁺5VとGNDが2つありますが、それぞれ1つだけ繋ぎます

PC-6001エッジコネクタ側端子

ROMカートリッジを立てた状態で真上から見た時の配置です。

Arduino Mega2560 R3側端子

Arudiono側コード

ArduinoのIDEを使ってコードをコンパイル＆書き込みします。通信速度は57600bpsにしていますが、PC側と速度が合っていれば115200bpsに書き換えてもOKです。

//
// PC-6001 ROM Cart Reader
//

const int PIN_ROM1  = 2;
const int PIN_ROM2  = 3;

word ReadAddr;
const int START_ADDR      = 0x0000;
const int END_CHECK_ADDR  = 0x2000;

void setup()
{
	// all output(Address Bus Lower, A0-A7)
	DDRA = B11111111;
	PORTA = B00000000;
	// all output(Address Bus Higher, A8-A14)
	DDRC = B11111111;
	PORTC = B00000000;
	// all input(Data Bus, D0-D7)
	DDRL = B00000000;

	pinMode(PIN_ROM1, OUTPUT);
	pinMode(PIN_ROM2, OUTPUT);
	digitalWrite(PIN_ROM1, HIGH);
	digitalWrite(PIN_ROM2, HIGH);
	
	Serial.begin(57600, SERIAL_8N1);
	Serial.flush();

	ReadAddr = START_ADDR;
	
	//Serial.println( "start loop. wait..." );

	// 開始待ち
	Serial.flush();
	while (true)
	{
		if (Serial.available() > 0)
		{
			int incomingByte = Serial.read();
			Serial.flush();
			delay(100);
			break;
		}
	}
}

void ReadRom(byte PortPin)
{
	while(true)
	{
		PORTA = ReadAddr & 0xff;  // low addr
		PORTC = ReadAddr >> 8;    // high addr
		delayMicroseconds(1);
		
		digitalWrite(PortPin, LOW);
		delayMicroseconds(1);
		
		int v = PINL;
		Serial.write(v);
		
		digitalWrite(PortPin, HIGH);
		
		ReadAddr++;
		if (ReadAddr == END_CHECK_ADDR)
		{
			ReadAddr = START_ADDR;
			break;
		}
	}
}

void loop()
{
	ReadRom(PIN_ROM1);
	ReadRom(PIN_ROM2);
	while(true){}
}	

使い方

PC側からArduinoに何でもいいのでデータを送ると、Arduinoから読み込んだROMの内容を送り返してきます。

（例）PC側通信ソフトにAcknowrichを使った場合

• ArduinoのIDEは終了させておきます（COMポートの番号は覚えておきましょう）
• Acknowrichを起動して、COMポートを選択します。通信速度を57600bpsにします
• Arduino Mega2560 R3のリセットボタンを押します
• Acknowrichの画面上部の入力欄に適当に1文字入れてエンターキーを押します
• Arduinoからデータが返ってきます
• 保存して終わりです

補足説明：Arduino側信号線の意味

Arduinoは一般的に各端子のON/OFFや状態の読込みは1端子単位で行います。アドレスバスが16本ある場合、A0-A15それぞれをON/OFF設定することになるのですが、それだと面倒なので、ArduinoのCPUであるATMEGAのポートを直接コントロールすることで、8本単位で信号を読み書きする事が出来るようになっています。

具体的には、以下のページを参考にしました。（ページ内の表示記述ミスがあるので注意）

Arduino処理速度とメモリー使用改善の策

この表(ポートからみたArduinoのピン番号)によると、8ビット単位で制御できるのは、PA0-7, PB0-7, PC0-7, PL0-7です。PF0-7とPK0-7も使えるのですが、デフォルト設定がアナログ用なので除外します。また、ピン番号の方をみると、ポートPB0-7はピン番号が離れたところにあります（D53,D52,D51,D50,D10,D11,D12,D13）。これは配線する時のミスになりそうですから除外します。

となると、残りはPA0-7, PC0-7, PL0-7で、ちょうどいい感じにアドレスバス16本＋データバス8本に割り当てられますね。

補足説明：PC-6001側信号線の意味

ROM1とROM2信号がありますが、これはROMカートリッジ内にROMが2個あり、それぞれを選択するための信号です。Active Lowです。両方を同時にLowにすると良くないことが起きます。

PC-6001メモリマップ

Z80からROMにアクセスする時は、MREQ、RD、アドレスバスといったZ80の信号をやりくりする必要があるのですが、PC-6001は内部の回路で外部ROM選択用の信号を生成していて、それが拡張コネクタに出ています。ただし、この信号に対応していないROMカートリッジの場合は、この信号を使うことは出来ません。PC-6001mkII以降専用のROMカートリッジが該当すると思われます（未確認）。そのようなカートリッジの場合は、MREQやRD信号を使ってROMにアクセスすることになります。（下図参照）